"""
second_derivative(g::TensorGrid, stencil_set, direction)    
second_derivative(g::EquidistantGrid, stencil_set, direction)

Creates the second derivative operator `D2` as a `LazyTensor`

`D2` approximates the second-derivative d²/dξ² on `g` along the coordinate
dimension specified by `direction`.

See also: [`VolumeOperator`](@ref), [`LazyTensors.inflate`](@ref).
"""
function second_derivative(g::TensorGrid, stencil_set, direction)
    if direction ∉ Interval(0, ndims(g))
        throw(DomainError(direction, "Direction must be inside [0, $(ndims(g))]."))
    end
    D₂ = second_derivative(g.grids[direction], stencil_set)
    return LazyTensors.inflate(D₂, size(g), direction)
end

function second_derivative(g::EquidistantGrid, stencil_set::StencilSet, direction)
    return second_derivative(TensorGrid(g), stencil_set, direction)
end

"""
    second_derivative(g::EquidistantGrid, stencil_set::::StencilSet)

The second derivative operator on an `EquidistantGrid`. 
Uses the `D2` stencil in `stencil_set`.
"""
function second_derivative(g::EquidistantGrid, stencil_set::StencilSet)
    inner_stencil = parse_stencil(stencil_set["D2"]["inner_stencil"])
    closure_stencils = parse_stencil.(stencil_set["D2"]["closure_stencils"])
    return second_derivative(g, inner_stencil, closure_stencils)
end

"""
    second_derivative(g::EquidistantGrid, inner_stencil::Stencil, closure_stencils)

The second derivative operator on an `EquidistantGrid`, given `inner_stencil` and
`closure_stencils`.
"""
function second_derivative(g::EquidistantGrid, inner_stencil::Stencil, closure_stencils)
    h⁻¹ = inverse_spacing(g)
    return VolumeOperator(g, scale(inner_stencil,h⁻¹^2), scale.(closure_stencils,h⁻¹^2), even)
end