Mercurial > repos > public > sbplib_julia

comparison src/SbpOperators/boundaryops/boundary_operator.jl @ 651:67639b1c99ea

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Merged feature/volume_and_boundary_operators
author Vidar Stiernström <vidar.stiernstrom@it.uu.se>
date Wed, 20 Jan 2021 17:52:55 +0100
parents 9f27f451d0a0
children b4acd25943f4 69700b0b1452
comparison
equal deleted inserted replaced
615:52749b687a67 651:67639b1c99ea
1 """
2 boundary_operator(grid,closure_stencil,boundary)
3
4 Creates a boundary operator on a `Dim`-dimensional grid for the
5 specified `boundary`. The action of the operator is determined by `closure_stencil`.
6
7 When `Dim=1`, the corresponding `BoundaryOperator` tensor mapping is returned.
8 When `Dim>1`, the `BoundaryOperator` `op` is inflated by the outer product
9 of `IdentityMappings` in orthogonal coordinate directions, e.g for `Dim=3`,
10 the boundary restriction operator in the y-direction direction is `Ix⊗op⊗Iz`.
11 """
12 function boundary_operator(grid::EquidistantGrid{Dim,T}, closure_stencil::Stencil{T}, boundary::CartesianBoundary) where {Dim,T}
13 #TODO:Check that dim(boundary) <= Dim?
14
15 # Create 1D boundary operator
16 r = region(boundary)
17 d = dim(boundary)
18 op = BoundaryOperator(restrict(grid, d), closure_stencil, r)
19
20 # Create 1D IdentityMappings for each coordinate direction
21 one_d_grids = restrict.(Ref(grid), Tuple(1:Dim))
22 Is = IdentityMapping{T}.(size.(one_d_grids))
23
24 # Formulate the correct outer product sequence of the identity mappings and
25 # the boundary operator
26 parts = Base.setindex(Is, op, d)
27 return foldl(⊗, parts)
28 end
29
30 """
31 BoundaryOperator{T,R,N} <: TensorMapping{T,0,1}
32
33 Implements the boundary operator `op` for 1D as a `TensorMapping`
34
35 `op` is the restriction of a grid function to the boundary using some closure `Stencil{T,N}`.
36 The boundary to restrict to is determined by `R`.
37 `op'` is the prolongation of a zero dimensional array to the whole grid using the same closure stencil.
38 """
39 struct BoundaryOperator{T,R<:Region,N} <: TensorMapping{T,0,1}
40 stencil::Stencil{T,N}
41 size::Int
42 end
43
44 BoundaryOperator{R}(stencil::Stencil{T,N}, size::Int) where {T,R,N} = BoundaryOperator{T,R,N}(stencil, size)
45
46 """
47 BoundaryOperator(grid::EquidistantGrid{1}, closure_stencil, region)
48
49 Constructs the BoundaryOperator with stencil `closure_stencil` for a one-dimensional `grid`, restricting to
50 to the boundary specified by `region`.
51 """
52 function BoundaryOperator(grid::EquidistantGrid{1}, closure_stencil::Stencil{T,N}, region::Region) where {T,N}
53 return BoundaryOperator{T,typeof(region),N}(closure_stencil,size(grid)[1])
54 end
55
56 """
57 closure_size(::BoundaryOperator)
58 The size of the closure stencil.
59 """
60 closure_size(::BoundaryOperator{T,R,N}) where {T,R,N} = N
61
62 LazyTensors.range_size(op::BoundaryOperator) = ()
63 LazyTensors.domain_size(op::BoundaryOperator) = (op.size,)
64
65 function LazyTensors.apply(op::BoundaryOperator{T,Lower}, v::AbstractVector{T}) where T
66 apply_stencil(op.stencil,v,1)
67 end
68
69 function LazyTensors.apply(op::BoundaryOperator{T,Upper}, v::AbstractVector{T}) where T
70 apply_stencil_backwards(op.stencil,v,op.size)
71 end
72
73 function LazyTensors.apply_transpose(op::BoundaryOperator{T,Lower}, v::AbstractArray{T,0}, i::Index{Lower}) where T
74 return op.stencil[Int(i)-1]*v[]
75 end
76
77 function LazyTensors.apply_transpose(op::BoundaryOperator{T,Upper}, v::AbstractArray{T,0}, i::Index{Upper}) where T
78 return op.stencil[op.size[1] - Int(i)]*v[]
79 end
80
81 # Catch all combinations of Lower, Upper and Interior not caught by the two previous methods.
82 function LazyTensors.apply_transpose(op::BoundaryOperator{T}, v::AbstractArray{T,0}, i::Index) where T
83 return zero(T)
84 end
85
86 function LazyTensors.apply_transpose(op::BoundaryOperator{T}, v::AbstractArray{T,0}, i) where T
87 r = getregion(i, closure_size(op), op.size)
88 apply_transpose(op, v, Index(i,r))
89 end